kitapta ne kadar refers varsa ayrıntılı olarak belirtir (yeni sayfada) Hazır Excel Makroları (VBA) | Excel Programları

Makroyu Kopyala

'Excel Makro (VBA) online eğitimleri için: https://www.excelsizeyeter.com/excelsizeyeter.com/udemy_giris.php adresine tıklayınız. Bir eğitim alana bir eğitim bedavadır. İkinci eğitim olarak Excel, Excel pratik çözümler, finans eğitimleri vb. alabilirsiniz. 
 
Option Explicit

Public Sub ListNamesInWorkbook()
        ' by J.E. McGimpsey
        ' Thanks to Tom Ogilvy for help with overflow.
        Const SHEETNAME As String = "Names in *"
        Const ROWLIM As Long = 65500
        Dim nameSht As Worksheet
        Dim destRng As Range
        Dim cell As Range
        Dim wkSht As Worksheet
        Dim shCnt As Long
        Dim i As Long
        Dim oldScreenUpdating As Boolean
        
        With Application
            oldScreenUpdating = .ScreenUpdating
            .ScreenUpdating = False
        End With
        shCnt = 0
        ListNamesAddSheet nameSht, shCnt
        ' list Workbook-level names
        Set destRng = nameSht.Range("A5")
        With destRng.Offset(-1, 0)
            .Value = "Workbook-Level names"
            .Font.Bold = True
        End With
        With ActiveWorkbook.Names
            If .Count Then
                destRng.Offset(0, 1).ListNames  'only workbook level
                Set destRng = destRng.Offset(0, 1).End(xlDown).Offset(1, -1)
            Else
                destRng.Offset(0, 1).Value = "None"
                Set destRng = destRng.Offset(0, 1)
            End If
        End With
        With destRng.Resize(1, 3).Borders(xlEdgeBottom)
            .LineStyle = xlContinuous
            .Weight = xlThin
            .ColorIndex = 5
        End With
        Set destRng = destRng.Offset(1, 0)
        For Each wkSht In ActiveWorkbook.Worksheets
            With destRng
                .Value = "Names in sheet """ & wkSht.Name & """"
                .Font.Bold = True
                Set destRng = .Offset(1, 0)
            End With
            With wkSht.Names
                If .Count Then
                    For i = 1 To .Count
                        With .Item(i)
                            destRng.Offset(0, 1) = Mid(.Name, InStr(.Name, "!") + 1)
                            destRng.Offset(0, 2) = "'" & .RefersTo
                            Set destRng = destRng.Offset(1, 0)
                            If destRng.Row > ROWLIM Then
                                ListNamesAddSheet nameSht, shCnt
                                Set destRng = nameSht.Range("A5")
                                destRng.Offset(-1, 0).Value = _
                                    "Names in sheet """ & wkSht.Name & """"
                            End If
                        End With
                    Next i
                Else
                    destRng.Offset(0, 1).Value = "None"
                    Set destRng = destRng.Offset(1, 0)
                End If
            End With
            With destRng.Resize(1, 4).Borders(xlEdgeBottom)
                .LineStyle = xlContinuous
                .Weight = xlThin
                .ColorIndex = 5
            End With
            Set destRng = destRng.Offset(1, 0)
        Next wkSht
        With Application
            .StatusBar = False
            .ScreenUpdating = oldScreenUpdating
        End With
    End Sub

Private Sub ListNamesAddSheet( _
                nameSht As Worksheet, shtCnt As Long)
        Const SHEETNAME As String = "Names in "
        Const SHEETTITLE As String = "Names in $ as of "
        Const DATEFORMAT As String = "dd MMM yyyy hh:mm"
        Dim shtName As String

With ActiveWorkbook
            ' Delete existing sheet and create new one
            shtName = Left(SHEETNAME & .Name, 28)
            shtCnt = shtCnt + 1
            If shtCnt > 1 Then _
                shtName = shtName & "_" & Format(shtCnt, "00")
             On Error Resume Next
            Application.DisplayAlerts = False
            .Worksheets(shtName).Delete
            Application.DisplayAlerts = True
            On Error GoTo 0
            Set nameSht = .Worksheets.Add( _
                    after:=Sheets(Sheets.Count))
        End With

With nameSht
            ' Format headers
            .Name = shtName
            .Columns(1).ColumnWidth = 30
            .Columns(2).ColumnWidth = 20
            .Columns(3).ColumnWidth = 90
            With .Range("B:C")
                .Font.Size = 9
                .HorizontalAlignment = xlLeft
                .EntireColumn.WrapText = True
            End With
            With .Range("A1")
                .Value = Application.Substitute(SHEETTITLE, "$", _
                        ActiveWorkbook.Name) & Format(Now, DATEFORMAT)
                With .Font
                    .Bold = True
                    .ColorIndex = 5
                    .Size = 14
                End With
            End With
            With .Range("A3").Resize(1, 3)
                .Value = Array("Sheet", "Name", "Refers To")
                With .Font
                    .ColorIndex = 13
                    .Bold = True
                    .Size = 12
                End With
                .HorizontalAlignment = xlCenter
                With .Borders(xlEdgeBottom)
                    .LineStyle = xlDouble
                    .Weight = xlThick
                    .ColorIndex = 5
                End With
            End With
        End With
    End Sub

Benzer Sonuçlar
No	Makro Adı
1	kitapta ne kadar refers varsa ayrıntılı olarak belirtir (yeni sayfada)
2	kitapta ne kadar formül varsa ayrıntılı olarak belirtir (yeni sayfada)
3	ayları sayfa olarak ekler günleri ayrıntılı olarak belirtir
4	excelde kendi eklenti ve fonksiyonlarınızı oluşturun
5	işgünlerine ait sheet açmak.
6	listbox ve combobox'a veri girmek
7	şifrelemede son nokta
8	sheetleri bir sheette toplamak
9	a1den a3000'e kadar olan hücrelerde eğer herhangi bir veri varsa kırmızı yapar ve satırı tamamen sayfa 3'e gönder
10	excel operatörleri hk
11	partisyon belirt ne kadar dosya varsa listelesin
12	tüm makroların listesi
13	hücrede bir sonraki ayın gün sayısı kadar gün ilave etme
14	İçerik Tablosu Yaratın: Çalışma kitabınızda 100ün üzerinde çalışma sayfanız olduğunu varsayalım. Ve şimdi gezinmek zor. Bu makro kodunun her şeyi kurtaracağından endişelenmeyin. Bu kodu çalıştırdığınızda, yeni bir çalışma sayfası oluşturacak ve onlara bir köprü içeren çalışma sayfalarının & nbsp; bir dizini oluşturacaktır.
15	bir kitaptaki sayfalara başka bir kitaba taşımak
16	korumalı hücrelere sıralama yapmak?
17	dosya klasör ekle
18	userform'u otomatik boyutlandırma
19	tüm kitapta istenilen sayfada sütunlardaki en son dolu hücreleri bildirir
20	adlandırılmış hücreleri wb_names sayfasında ayrıntılı listeler

Benzer Sonuçlar

Makro Adı

kitapta ne kadar refers varsa ayrıntılı olarak belirtir (yeni sayfada)

kitapta ne kadar formül varsa ayrıntılı olarak belirtir (yeni sayfada)

ayları sayfa olarak ekler günleri ayrıntılı olarak belirtir

excelde kendi eklenti ve fonksiyonlarınızı oluşturun

işgünlerine ait sheet açmak.

listbox ve combobox'a veri girmek

şifrelemede son nokta

sheetleri bir sheette toplamak

a1den a3000'e kadar olan hücrelerde eğer herhangi bir veri varsa kırmızı yapar ve satırı tamamen sayfa 3'e gönder

excel operatörleri hk