rakamı / sayıyı İngilizce yazıya çevirmek (Dolar ve cent para birimi şeklinde) Hazır Excel Makroları (VBA) | Excel Programları

Makroyu Kopyala

'Excel Makro (VBA) online eğitimleri için: https://www.excelsizeyeter.com/excelsizeyeter.com/udemy_giris.php adresine tıklayınız. Bir eğitim alana bir eğitim bedavadır. İkinci eğitim olarak Excel, Excel pratik çözümler, finans eğitimleri vb. alabilirsiniz. 
 
'Kullanılışı
'=SpellNumber(A1) yada
'=SpellNumber(250) şeklinde kullanabilirsini

Option Explicit

'****************
' Main Function *
'****************

Function SpellNumber(ByVal MyNumber)
    Dim Dollars, Cents, Temp
    Dim DecimalPlace, Count
    ReDim Place(9) As String
    Place(2) = " Thousand "
    Place(3) = " Million "
    Place(4) = " Billion "
    Place(5) = " Trillion "
    ' String representation of amount.
    MyNumber = Trim(Str(MyNumber))
    ' Position of decimal place 0 if none.
    DecimalPlace = InStr(MyNumber, ".")
    ' Convert cents and set MyNumber to dollar amount.
    If DecimalPlace > 0 Then
        Cents = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
                  "00", 2))
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    End If
    Count = 1
    Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then Dollars = Temp & Place(Count) & Dollars
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    Select Case Dollars
        Case ""
            Dollars = "No Dollars"
        Case "One"
            Dollars = "One Dollar"
         Case Else
            Dollars = Dollars & " Dollars"
    End Select
    Select Case Cents
        Case ""
            Cents = " and No Cents"
        Case "One"
            Cents = " and One Cent"
              Case Else
            Cents = " and " & Cents & " Cents"
    End Select
    SpellNumber = Dollars & Cents
End Function
      
' Converts a number from 100-999 into text
Function GetHundreds(ByVal MyNumber)
    Dim Result As String
    If Val(MyNumber) = 0 Then Exit Function
    MyNumber = Right("000" & MyNumber, 3)
    ' Convert the hundreds place.
    If Mid(MyNumber, 1, 1) <> "0" Then
        Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
    End If
    ' Convert the tens and ones place.
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & GetTens(Mid(MyNumber, 2))
    Else
        Result = Result & GetDigit(Mid(MyNumber, 3))
    End If
    GetHundreds = Result
End Function
      
' Converts a number from 10 to 99 into text.
Function GetTens(TensText)
    Dim Result As String
    Result = ""           ' Null out the temporary function value.
    If Val(Left(TensText, 1)) = 1 Then   ' If value between 10-19...
        Select Case Val(TensText)
            Case 10: Result = "Ten"
            Case 11: Result = "Eleven"
            Case 12: Result = "Twelve"
            Case 13: Result = "Thirteen"
            Case 14: Result = "Fourteen"
            Case 15: Result = "Fifteen"
            Case 16: Result = "Sixteen"
            Case 17: Result = "Seventeen"
            Case 18: Result = "Eighteen"
            Case 19: Result = "Nineteen"
            Case Else
        End Select
    Else                                 ' If value between 20-99...
        Select Case Val(Left(TensText, 1))
            Case 2: Result = "Twenty "
            Case 3: Result = "Thirty "
            Case 4: Result = "Forty "
            Case 5: Result = "Fifty "
            Case 6: Result = "Sixty "
            Case 7: Result = "Seventy "
            Case 8: Result = "Eighty "
            Case 9: Result = "Ninety "
            Case Else
        End Select
        Result = Result & GetDigit _
            (Right(TensText, 1))  ' Retrieve ones place.
    End If
    GetTens = Result
End Function
     
' Converts a number from 1 to 9 into text.
Function GetDigit(Digit)
    Select Case Val(Digit)
        Case 1: GetDigit = "One"
        Case 2: GetDigit = "Two"
        Case 3: GetDigit = "Three"
        Case 4: GetDigit = "Four"
        Case 5: GetDigit = "Five"
        Case 6: GetDigit = "Six"
        Case 7: GetDigit = "Seven"
        Case 8: GetDigit = "Eight"
        Case 9: GetDigit = "Nine"
        Case Else: GetDigit = ""
    End Select
End Function

Benzer Sonuçlar
No	Makro Adı
1	rakamı / sayıyı İngilizce yazıya çevirmek (Dolar ve cent para birimi şeklinde)
2	Sayıyı / Rakamı Yazıya (Metne) Çevirme Fonksiyonu (Türkçe)
3	makrolar kutusu ve makrolar görünsün
4	sayıyı dolar olarak okuma =dollartext(a1)
5	rakamı yazıya çevirme makrosu
6	şifrelemede son nokta
7	sayıyı rakama kuruşlu çevirmek
8	metin kutusuna girlilen yazinin para birimi şeklinde olmasi
9	excelde kendi eklenti ve fonksiyonlarınızı oluşturun
10	textboxa(metin kutusuna) girlilen yazının para birimi şeklinde olması
11	hücre renkleri ile ilgili kodlar
12	multipage zemin rengi
13	sayıyı paranteze alma örnek: 3- = (3) sayının yanına çizgi şart
14	excel operatörleri hk
15	userformun açılış sayısını sınırlamak (demo yapmak)
16	textboxa girerken her üç rakamın arasına bir nokta koyma
17	menü çubuğunun silinmesi ve özel bir menünün oluşturulması
18	hücredeki sayıyı alt veya üst karaktere ve normale çevirir. h2o, co2
19	excel sayfasında yazılanları texte çevirmek
20	microsoft outlookdan uyarı e-maili göndersin

Benzer Sonuçlar

Makro Adı

rakamı / sayıyı İngilizce yazıya çevirmek (Dolar ve cent para birimi şeklinde)

Sayıyı / Rakamı Yazıya (Metne) Çevirme Fonksiyonu (Türkçe)

makrolar kutusu ve makrolar görünsün

sayıyı dolar olarak okuma =dollartext(a1)

rakamı yazıya çevirme makrosu

şifrelemede son nokta

sayıyı rakama kuruşlu çevirmek

metin kutusuna girlilen yazinin para birimi şeklinde olmasi

excelde kendi eklenti ve fonksiyonlarınızı oluşturun

textboxa(metin kutusuna) girlilen yazının para birimi şeklinde olması