workbook ta yazdırma komutu Hazır Excel Makroları (VBA) | Excel Programları

Makroyu Kopyala

'Excel Makro (VBA) online eğitimleri için: https://www.excelsizeyeter.com/excelsizeyeter.com/udemy_giris.php adresine tıklayınız. Bir eğitim alana bir eğitim bedavadır. İkinci eğitim olarak Excel, Excel pratik çözümler, finans eğitimleri vb. alabilirsiniz. 
 
Private Sub Workbook_BeforePrint(Cancel As Boolean)
        'J.E. McGimpsey  http://www.mcgimpsey.com/excel/noprintrange.html
        Dim vFontArr As Variant
        Dim oWkSht As Worksheet
        Dim rNoPrintRange As Range
        Dim rCell As Range
        Dim rArea As Range
        Dim i As Long
        Dim bOldScreenUpdating As Boolean
        
        Cancel = True
        With Application
            .EnableEvents = False
            bOldScreenUpdating = .ScreenUpdating
            .ScreenUpdating = False
        End With
        For Each oWkSht In ActiveWindow.SelectedSheets
            On Error Resume Next
            Set rNoPrintRange = oWkSht.Range("NoPrintRange")
            On Error GoTo 0
            If Not rNoPrintRange Is Nothing Then
                With rNoPrintRange
                    ReDim vFontArr(1 To .Count)
                    i = 1
                    For Each rArea In .Areas
                        For Each rCell In rArea
                            With rCell
                                vFontArr(i) = .Font.ColorIndex
                                If .Interior.ColorIndex = xlColorIndexNone Then
                                    .Font.Color = RGB(255, 255, 255) 'white
                                Else
                                    .Font.ColorIndex = .Interior.ColorIndex
                                End If
                            i = i + 1
                            End With
                        Next rCell
                    Next rArea
                    oWkSht.PrintOut
                    i = 1
                    For Each rArea In .Areas
                        For Each rCell In rArea
                            rCell.Font.ColorIndex = vFontArr(i)
                            i = i + 1
                        Next rCell
                    Next rArea
                End With
            Else
                oWkSht.PrintOut
            End If
            Set rNoPrintRange = Nothing
        Next oWkSht
        With Application
            .ScreenUpdating = bOldScreenUpdating
            .EnableEvents = True
        End With
    End Sub

Benzer Sonuçlar
No	Makro Adı
1	workbook ta yazdırma komutu
2	açık iki excel dosyasından sadece birini kapatmak.
3	wordpada yazdırmak istediğiniz bir metni excel içerisinden yazdırmak için
4	peşpeşe bul komutu
5	filigran yazdırma (sayfa artalanına silik yazı)
6	çalışma kitabının tümünü yazdırma
7	kitapta yazdırmayı iptal etme
8	yazdırmak için süzme şart olsun
9	hücreleri doldurmadan yazdırmaz
10	hücrelerden biri veya birkaçı boş olunca yazdırmayı iptal etme
11	seçilen alanları bir kağıtta yazdırır eder
12	seçilenin yazdırılması ve sorulması
13	açılış makrosu(aktif pencerede mesaj verir.)
14	mükemmel sağ fareye menüsünü siler ve yazdır, baskı önizle, sayfa yapısını ekler
15	klasör ve dosya makrolarındaki yolları kendine göre düzenle
16	aktif hücrenin yazdırılması
17	sayfayı yazdırırken çalışma kitabınızın adı ile yazdırır
18	aktif çalışma kitabının adını aktif hücreye yazdırır
19	açık olan dosyanın bulunduğu yeri öğrenmek
20	veri olan sayfaları yazdırma

Benzer Sonuçlar

Makro Adı

workbook ta yazdırma komutu

açık iki excel dosyasından sadece birini kapatmak.

wordpada yazdırmak istediğiniz bir metni excel içerisinden yazdırmak için

peşpeşe bul komutu

filigran yazdırma (sayfa artalanına silik yazı)

çalışma kitabının tümünü yazdırma

kitapta yazdırmayı iptal etme

yazdırmak için süzme şart olsun

hücreleri doldurmadan yazdırmaz

hücrelerden biri veya birkaçı boş olunca yazdırmayı iptal etme